Lomiri
Loading...
Searching...
No Matches
Stage.qml
1/*
2 * Copyright (C) 2014-2017 Canonical Ltd.
3 * Copyright (C) 2021 UBports Foundation
4 *
5 * This program is free software; you can redistribute it and/or modify
6 * it under the terms of the GNU General Public License as published by
7 * the Free Software Foundation; version 3.
8 *
9 * This program is distributed in the hope that it will be useful,
10 * but WITHOUT ANY WARRANTY; without even the implied warranty of
11 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12 * GNU General Public License for more details.
13 *
14 * You should have received a copy of the GNU General Public License
15 * along with this program. If not, see <http://www.gnu.org/licenses/>.
16 */
17
18import QtQuick 2.15
19import QtQml 2.15
20import QtQuick.Window 2.2
21import Lomiri.Components 1.3
22import QtMir.Application 0.1
23import "../Components/PanelState"
24import "../Components"
25import Utils 0.1
26import Lomiri.Gestures 0.1
27import GlobalShortcut 1.0
28import GSettings 1.0
29import "Spread"
30import "Spread/MathUtils.js" as MathUtils
31import ProcessControl 0.1
32import WindowManager 1.0
33
34FocusScope {
35 id: root
36 anchors.fill: parent
37
38 property QtObject applicationManager
39 property QtObject topLevelSurfaceList
40 property bool altTabPressed
41 property url background
42 property alias backgroundSourceSize: wallpaper.sourceSize
43 property int dragAreaWidth
44 property real nativeHeight
45 property real nativeWidth
46 property QtObject orientations
47 property int shellOrientation
48 property int shellOrientationAngle
49 property bool spreadEnabled: true // If false, animations and right edge will be disabled
50 property bool suspended
51 property bool oskEnabled: false
52 property bool lightMode: false
53 property rect inputMethodRect
54 property real rightEdgePushProgress: 0
55 property Item availableDesktopArea
56 property PanelState panelState
57
58 // Whether outside forces say that the Stage may have focus
59 property bool allowInteractivity
60
61 readonly property bool interactive: (state === "staged" || state === "stagedWithSideStage" || state === "windowed") && allowInteractivity
62
63 // Configuration
64 property string mode: "staged"
65
66 readonly property var temporarySelectedWorkspace: state == "spread" ? screensAndWorkspaces.activeWorkspace : null
67 property bool workspaceEnabled: (mode == "windowed" && settings.enableWorkspace) || settings.forceEnableWorkspace
68
69 // Used by the tutorial code
70 readonly property real rightEdgeDragProgress: rightEdgeDragArea.dragging ? rightEdgeDragArea.progress : 0 // How far left the stage has been dragged
71
72 // used by the snap windows (edge maximize) feature
73 readonly property alias previewRectangle: fakeRectangle
74
75 readonly property bool spreadShown: state == "spread"
76 readonly property var mainApp: priv.focusedAppDelegate ? priv.focusedAppDelegate.application : null
77
78 // application windows never rotate independently
79 property int mainAppWindowOrientationAngle: shellOrientationAngle
80
81 property bool orientationChangesEnabled: !priv.focusedAppDelegate || priv.focusedAppDelegate.orientationChangesEnabled
82
83 property int supportedOrientations: {
84 if (mainApp) {
85 switch (mode) {
86 case "staged":
87 return mainApp.supportedOrientations;
88 case "stagedWithSideStage":
89 var orientations = mainApp.supportedOrientations;
90 orientations |= Qt.LandscapeOrientation | Qt.InvertedLandscapeOrientation;
91 if (priv.sideStageItemId) {
92 // If we have a sidestage app, support Portrait orientation
93 // so that it will switch the sidestage app to mainstage on rotate to portrait
94 orientations |= Qt.PortraitOrientation|Qt.InvertedPortraitOrientation;
95 }
96 return orientations;
97 }
98 }
99
100 return Qt.PortraitOrientation |
101 Qt.LandscapeOrientation |
102 Qt.InvertedPortraitOrientation |
103 Qt.InvertedLandscapeOrientation;
104 }
105
106 GSettings {
107 id: settings
108 schema.id: "com.lomiri.Shell"
109 }
110
111 property int launcherLeftMargin : 0
112
113 Binding {
114 target: topLevelSurfaceList
115 restoreMode: Binding.RestoreBinding
116 property: "rootFocus"
117 value: interactive
118 }
119
120 onInteractiveChanged: {
121 // Stage must have focus before activating windows, including null
122 if (interactive) {
123 focus = true;
124 }
125 }
126
127 onAltTabPressedChanged: {
128 root.focus = true;
129 if (altTabPressed) {
130 if (root.spreadEnabled) {
131 altTabDelayTimer.start();
132 }
133 } else {
134 // Alt Tab has been released, did we already go to spread?
135 if (priv.goneToSpread) {
136 priv.goneToSpread = false;
137 } else {
138 // No we didn't, do a quick alt-tab
139 if (appRepeater.count > 1) {
140 appRepeater.itemAt(1).activate();
141 } else if (appRepeater.count > 0) {
142 appRepeater.itemAt(0).activate(); // quick alt-tab to the only (minimized) window should still activate it
143 }
144 }
145 }
146 }
147
148 Timer {
149 id: altTabDelayTimer
150 interval: 140
151 repeat: false
152 onTriggered: {
153 if (root.altTabPressed) {
154 priv.goneToSpread = true;
155 }
156 }
157 }
158
159 // For MirAL window management
160 WindowMargins {
161 normal: Qt.rect(0, root.mode === "windowed" ? priv.windowDecorationHeight : 0, 0, 0)
162 dialog: normal
163 }
164
165 property Item itemConfiningMouseCursor: !spreadShown && priv.focusedAppDelegate && priv.focusedAppDelegate.window && priv.focusedAppDelegate.window.confinesMousePointer ?
166 priv.focusedAppDelegate.clientAreaItem : null;
167
168 signal itemSnapshotRequested(Item item)
169
170 // functions to be called from outside
171 function updateFocusedAppOrientation() { /* TODO */ }
172 function updateFocusedAppOrientationAnimated() { /* TODO */}
173
174 function closeSpread() {
175 spreadItem.highlightedIndex = -1;
176 priv.goneToSpread = false;
177 }
178
179 onSpreadEnabledChanged: {
180 if (!spreadEnabled && spreadShown) {
181 closeSpread();
182 }
183 }
184
185 onRightEdgePushProgressChanged: {
186 if (spreadEnabled && rightEdgePushProgress >= 1) {
187 priv.goneToSpread = true
188 }
189 }
190
191 GSettings {
192 id: lifecycleExceptions
193 schema.id: "com.canonical.qtmir"
194 }
195
196 function isExemptFromLifecycle(appId) {
197 var shortAppId = appId.split('_')[0];
198 for (var i = 0; i < lifecycleExceptions.lifecycleExemptAppids.length; i++) {
199 if (shortAppId === lifecycleExceptions.lifecycleExemptAppids[i]) {
200 return true;
201 }
202 }
203 return false;
204 }
205
206 GlobalShortcut {
207 id: closeFocusedShortcut
208 shortcut: Qt.AltModifier|Qt.Key_F4
209 onTriggered: {
210 if (priv.focusedAppDelegate) {
211 priv.focusedAppDelegate.close();
212 }
213 }
214 }
215
216 GlobalShortcut {
217 id: showSpreadShortcut
218 shortcut: Qt.MetaModifier|Qt.Key_W
219 active: root.spreadEnabled
220 onTriggered: priv.goneToSpread = true
221 }
222
223 GlobalShortcut {
224 id: toggleSideStageShortcut
225 shortcut: Qt.MetaModifier|Qt.Key_S
226 active: priv.sideStageEnabled
227 onTriggered: {
228 priv.toggleSideStage()
229 }
230 }
231
232 GlobalShortcut {
233 id: minimizeAllShortcut
234 shortcut: Qt.MetaModifier|Qt.ControlModifier|Qt.Key_D
235 onTriggered: priv.minimizeAllWindows()
236 active: root.state == "windowed"
237 }
238
239 GlobalShortcut {
240 id: maximizeWindowShortcut
241 shortcut: Qt.MetaModifier|Qt.ControlModifier|Qt.Key_Up
242 onTriggered: priv.focusedAppDelegate.requestMaximize()
243 active: root.state == "windowed" && priv.focusedAppDelegate && priv.focusedAppDelegate.canBeMaximized
244 }
245
246 GlobalShortcut {
247 id: maximizeWindowLeftShortcut
248 shortcut: Qt.MetaModifier|Qt.ControlModifier|Qt.Key_Left
249 onTriggered: {
250 switch (root.mode) {
251 case "stagedWithSideStage":
252 if (priv.focusedAppDelegate.stage == ApplicationInfoInterface.SideStage) {
253 priv.focusedAppDelegate.saveStage(ApplicationInfoInterface.MainStage);
254 priv.focusedAppDelegate.focus = true;
255 }
256 break;
257 case "windowed":
258 priv.focusedAppDelegate.requestMaximizeLeft()
259 break;
260 }
261 }
262 active: (root.state == "windowed" && priv.focusedAppDelegate && priv.focusedAppDelegate.canBeMaximizedLeftRight)
263 || (root.state == "stagedWithSideStage" && priv.focusedAppDelegate.stage == ApplicationInfoInterface.SideStage)
264 }
265
266 GlobalShortcut {
267 id: maximizeWindowRightShortcut
268 shortcut: Qt.MetaModifier|Qt.ControlModifier|Qt.Key_Right
269 onTriggered: {
270 switch (root.mode) {
271 case "stagedWithSideStage":
272 if (priv.focusedAppDelegate.stage == ApplicationInfoInterface.MainStage) {
273 priv.focusedAppDelegate.saveStage(ApplicationInfoInterface.SideStage);
274 priv.focusedAppDelegate.focus = true;
275 sideStage.show();
276 priv.updateMainAndSideStageIndexes()
277 }
278 break;
279 case "windowed":
280 priv.focusedAppDelegate.requestMaximizeRight()
281 break;
282 }
283 }
284 active: (root.state == "windowed" && priv.focusedAppDelegate && priv.focusedAppDelegate.canBeMaximizedLeftRight)
285 || (root.state == "stagedWithSideStage" && priv.focusedAppDelegate.stage == ApplicationInfoInterface.MainStage)
286 }
287
288 GlobalShortcut {
289 id: minimizeRestoreShortcut
290 shortcut: Qt.MetaModifier|Qt.ControlModifier|Qt.Key_Down
291 onTriggered: {
292 if (priv.focusedAppDelegate.anyMaximized) {
293 priv.focusedAppDelegate.requestRestore();
294 } else {
295 priv.focusedAppDelegate.requestMinimize();
296 }
297 }
298 active: root.state == "windowed" && priv.focusedAppDelegate
299 }
300
301 GlobalShortcut {
302 shortcut: Qt.AltModifier|Qt.Key_Print
303 onTriggered: root.itemSnapshotRequested(priv.focusedAppDelegate)
304 active: priv.focusedAppDelegate !== null
305 }
306
307 GlobalShortcut {
308 shortcut: Qt.ControlModifier|Qt.AltModifier|Qt.Key_T
309 onTriggered: {
310 // try in this order: snap pkg, new deb name, old deb name
311 var candidates = ["lomiri-terminal-app_lomiri-terminal-app", "lomiri-terminal-app", "com.lomiri.terminal_terminal"];
312 for (var i = 0; i < candidates.length; i++) {
313 if (priv.startApp(candidates[i]))
314 break;
315 }
316 }
317 }
318
319 GlobalShortcut {
320 id: showWorkspaceSwitcherShortcutLeft
321 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.Key_Left
322 active: !workspaceSwitcher.active && root.workspaceEnabled
323 onTriggered: {
324 root.focus = true;
325 workspaceSwitcher.showLeft()
326 }
327 }
328 GlobalShortcut {
329 id: showWorkspaceSwitcherShortcutRight
330 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.Key_Right
331 active: !workspaceSwitcher.active && root.workspaceEnabled
332 onTriggered: {
333 root.focus = true;
334 workspaceSwitcher.showRight()
335 }
336 }
337 GlobalShortcut {
338 id: showWorkspaceSwitcherShortcutUp
339 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.Key_Up
340 active: !workspaceSwitcher.active && root.workspaceEnabled
341 onTriggered: {
342 root.focus = true;
343 workspaceSwitcher.showUp()
344 }
345 }
346 GlobalShortcut {
347 id: showWorkspaceSwitcherShortcutDown
348 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.Key_Down
349 active: !workspaceSwitcher.active && root.workspaceEnabled
350 onTriggered: {
351 root.focus = true;
352 workspaceSwitcher.showDown()
353 }
354 }
355
356 GlobalShortcut {
357 id: moveAppShowWorkspaceSwitcherShortcutLeft
358 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.ShiftModifier|Qt.Key_Left
359 active: !workspaceSwitcher.active && root.workspaceEnabled && root.focusedAppDelegate
360 onTriggered: {
361 root.focus = true;
362 workspaceSwitcher.showLeftMoveApp(root.focusedAppDelegate.surface)
363 }
364 }
365 GlobalShortcut {
366 id: moveAppShowWorkspaceSwitcherShortcutRight
367 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.ShiftModifier|Qt.Key_Right
368 active: !workspaceSwitcher.active && root.workspaceEnabled && root.focusedAppDelegate
369 onTriggered: {
370 root.focus = true;
371 workspaceSwitcher.showRightMoveApp(root.focusedAppDelegate.surface)
372 }
373 }
374 GlobalShortcut {
375 id: moveAppShowWorkspaceSwitcherShortcutUp
376 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.ShiftModifier|Qt.Key_Up
377 active: !workspaceSwitcher.active && root.workspaceEnabled && root.focusedAppDelegate
378 onTriggered: {
379 root.focus = true;
380 workspaceSwitcher.showUpMoveApp(root.focusedAppDelegate.surface)
381 }
382 }
383 GlobalShortcut {
384 id: moveAppShowWorkspaceSwitcherShortcutDown
385 shortcut: Qt.AltModifier|Qt.ControlModifier|Qt.ShiftModifier|Qt.Key_Down
386 active: !workspaceSwitcher.active && root.workspaceEnabled && root.focusedAppDelegate
387 onTriggered: {
388 root.focus = true;
389 workspaceSwitcher.showDownMoveApp(root.focusedAppDelegate.surface)
390 }
391 }
392
393 QtObject {
394 id: priv
395 objectName: "DesktopStagePrivate"
396
397 function startApp(appId) {
398 if (root.applicationManager.findApplication(appId)) {
399 return root.applicationManager.requestFocusApplication(appId);
400 } else {
401 return root.applicationManager.startApplication(appId) !== null;
402 }
403 }
404
405 property var focusedAppDelegate: null
406 property var foregroundMaximizedAppDelegate: null // for stuff like drop shadow and focusing maximized app by clicking panel
407
408 property bool goneToSpread: false
409 property int closingIndex: -1
410 property int animationDuration: LomiriAnimation.FastDuration
411
412 function updateForegroundMaximizedApp() {
413 var found = false;
414 for (var i = 0; i < appRepeater.count && !found; i++) {
415 var item = appRepeater.itemAt(i);
416 if (item && item.visuallyMaximized) {
417 foregroundMaximizedAppDelegate = item;
418 found = true;
419 }
420 }
421 if (!found) {
422 foregroundMaximizedAppDelegate = null;
423 }
424 }
425
426 function minimizeAllWindows() {
427 for (var i = appRepeater.count - 1; i >= 0; i--) {
428 var appDelegate = appRepeater.itemAt(i);
429 if (appDelegate && !appDelegate.minimized) {
430 appDelegate.requestMinimize();
431 }
432 }
433 }
434
435 readonly property bool sideStageEnabled: root.mode === "stagedWithSideStage" &&
436 (root.shellOrientation == Qt.LandscapeOrientation ||
437 root.shellOrientation == Qt.InvertedLandscapeOrientation)
438 onSideStageEnabledChanged: {
439 for (var i = 0; i < appRepeater.count; i++) {
440 appRepeater.itemAt(i).refreshStage();
441 }
442 priv.updateMainAndSideStageIndexes();
443 }
444
445 property var mainStageDelegate: null
446 property var sideStageDelegate: null
447 property int mainStageItemId: 0
448 property int sideStageItemId: 0
449 property string mainStageAppId: ""
450 property string sideStageAppId: ""
451
452 onSideStageDelegateChanged: {
453 if (!sideStageDelegate) {
454 sideStage.hide();
455 }
456 }
457
458 function toggleSideStage() {
459 if (sideStage.shown) {
460 sideStage.hide();
461 } else {
462 sideStage.show();
463 updateMainAndSideStageIndexes()
464 }
465 }
466
467 function updateMainAndSideStageIndexes() {
468 if (root.mode != "stagedWithSideStage") {
469 priv.sideStageDelegate = null;
470 priv.sideStageItemId = 0;
471 priv.sideStageAppId = "";
472 priv.mainStageDelegate = appRepeater.itemAt(0);
473 priv.mainStageItemId = topLevelSurfaceList.idAt(0);
474 priv.mainStageAppId = topLevelSurfaceList.applicationAt(0) ? topLevelSurfaceList.applicationAt(0).appId : ""
475 return;
476 }
477
478 var choseMainStage = false;
479 var choseSideStage = false;
480
481 if (!root.topLevelSurfaceList)
482 return;
483
484 for (var i = 0; i < appRepeater.count && (!choseMainStage || !choseSideStage); ++i) {
485 var appDelegate = appRepeater.itemAt(i);
486 if (!appDelegate) {
487 // This might happen during startup phase... If the delegate appears and claims focus
488 // things are updated and appRepeater.itemAt(x) still returns null while appRepeater.count >= x
489 // Lets just skip it, on startup it will be generated at a later point too...
490 continue;
491 }
492 if (sideStage.shown && appDelegate.stage == ApplicationInfoInterface.SideStage
493 && !choseSideStage) {
494 priv.sideStageDelegate = appDelegate
495 priv.sideStageItemId = root.topLevelSurfaceList.idAt(i);
496 priv.sideStageAppId = root.topLevelSurfaceList.applicationAt(i).appId;
497 choseSideStage = true;
498 } else if (!choseMainStage && appDelegate.stage == ApplicationInfoInterface.MainStage) {
499 priv.mainStageDelegate = appDelegate;
500 priv.mainStageItemId = root.topLevelSurfaceList.idAt(i);
501 priv.mainStageAppId = root.topLevelSurfaceList.applicationAt(i).appId;
502 choseMainStage = true;
503 }
504 }
505 if (!choseMainStage && priv.mainStageDelegate) {
506 priv.mainStageDelegate = null;
507 priv.mainStageItemId = 0;
508 priv.mainStageAppId = "";
509 }
510 if (!choseSideStage && priv.sideStageDelegate) {
511 priv.sideStageDelegate = null;
512 priv.sideStageItemId = 0;
513 priv.sideStageAppId = "";
514 }
515 }
516
517 property int nextInStack: {
518 var mainStageIndex = priv.mainStageDelegate ? priv.mainStageDelegate.itemIndex : -1;
519 var sideStageIndex = priv.sideStageDelegate ? priv.sideStageDelegate.itemIndex : -1;
520 if (sideStageIndex == -1) {
521 return topLevelSurfaceList.count > 1 ? 1 : -1;
522 }
523 if (mainStageIndex == 0 || sideStageIndex == 0) {
524 if (mainStageIndex == 1 || sideStageIndex == 1) {
525 return topLevelSurfaceList.count > 2 ? 2 : -1;
526 }
527 return 1;
528 }
529 return -1;
530 }
531
532 readonly property real virtualKeyboardHeight: root.inputMethodRect.height
533
534 readonly property real windowDecorationHeight: units.gu(3)
535 }
536
537 Component.onCompleted: priv.updateMainAndSideStageIndexes()
538
539 Connections {
540 target: panelState
541 function onCloseClicked() { if (priv.focusedAppDelegate) { priv.focusedAppDelegate.close(); } }
542 function onMinimizeClicked() { if (priv.focusedAppDelegate) { priv.focusedAppDelegate.requestMinimize(); } }
543 function onRestoreClicked() { if (priv.focusedAppDelegate) { priv.focusedAppDelegate.requestRestore(); } }
544 }
545
546 Binding {
547 target: panelState
548 restoreMode: Binding.RestoreBinding
549 property: "decorationsVisible"
550 value: mode == "windowed" && priv.focusedAppDelegate !== null && priv.focusedAppDelegate.maximized && !root.spreadShown
551 }
552
553 Binding {
554 target: panelState
555 restoreMode: Binding.RestoreBinding
556 property: "title"
557 value: {
558 if (priv.focusedAppDelegate !== null) {
559 if (priv.focusedAppDelegate.maximized)
560 return priv.focusedAppDelegate.title
561 else
562 return priv.focusedAppDelegate.appName
563 }
564 return ""
565 }
566 when: priv.focusedAppDelegate
567 }
568
569 Binding {
570 target: panelState
571 restoreMode: Binding.RestoreBinding
572 property: "focusedPersistentSurfaceId"
573 value: {
574 if (priv.focusedAppDelegate !== null) {
575 if (priv.focusedAppDelegate.surface) {
576 return priv.focusedAppDelegate.surface.persistentId;
577 }
578 }
579 return "";
580 }
581 when: priv.focusedAppDelegate
582 }
583
584 Binding {
585 target: panelState
586 restoreMode: Binding.RestoreBinding
587 property: "dropShadow"
588 value: priv.focusedAppDelegate && !priv.focusedAppDelegate.maximized && priv.foregroundMaximizedAppDelegate !== null && mode == "windowed"
589 }
590
591 Binding {
592 target: panelState
593 restoreMode: Binding.RestoreBinding
594 property: "closeButtonShown"
595 value: priv.focusedAppDelegate && priv.focusedAppDelegate.maximized
596 }
597
598 Component.onDestruction: {
599 panelState.title = "";
600 panelState.decorationsVisible = false;
601 panelState.dropShadow = false;
602 }
603
604 Instantiator {
605 model: root.applicationManager
606 delegate: QtObject {
607 id: applicationDelegate
608 // TODO: figure out some lifecycle policy, like suspending minimized apps
609 // or something if running windowed.
610 // TODO: If the device has a dozen suspended apps because it was running
611 // in staged mode, when it switches to Windowed mode it will suddenly
612 // resume all those apps at once. We might want to avoid that.
613 property var requestedState: ApplicationInfoInterface.RequestedRunning
614 property bool temporaryAwaken: ProcessControl.awakenProcesses.indexOf(model.application.appId) >= 0
615
616 property var stateBinding: Binding {
617 target: model.application
618 property: "requestedState"
619 value: applicationDelegate.requestedState
620 restoreMode: Binding.RestoreBinding
621 }
622
623 property var lifecycleBinding: Binding {
624 target: model.application
625 property: "exemptFromLifecycle"
626 restoreMode: Binding.RestoreBinding
627 value: model.application
628 ? (!model.application.isTouchApp ||
629 isExemptFromLifecycle(model.application.appId) ||
630 applicationDelegate.temporaryAwaken)
631 : false
632
633 }
634
635 property var focusRequestedConnection: Connections {
636 target: model.application
637
638 function onFocusRequested() {
639 // Application emits focusRequested when it has no surface (i.e. their processes died).
640 // Find the topmost window for this application and activate it, after which the app
641 // will be requested to be running.
642
643 for (var i = 0; i < appRepeater.count; i++) {
644 var appDelegate = appRepeater.itemAt(i);
645 if (appDelegate.application.appId === model.application.appId) {
646 appDelegate.activate();
647 return;
648 }
649 }
650
651 console.warn("Application requested te be focused but no window for it. What should we do?");
652 }
653 }
654 }
655 }
656
657 states: [
658 State {
659 name: "spread"; when: priv.goneToSpread
660 PropertyChanges { target: floatingFlickable; enabled: true }
661 PropertyChanges { target: root; focus: true }
662 PropertyChanges { target: spreadItem; focus: true }
663 PropertyChanges { target: hoverMouseArea; enabled: true }
664 PropertyChanges { target: rightEdgeDragArea; enabled: false }
665 PropertyChanges { target: cancelSpreadMouseArea; enabled: true }
666 PropertyChanges { target: noAppsRunningHint; visible: (root.topLevelSurfaceList.count < 1) }
667 PropertyChanges { target: blurLayer; visible: true; blurRadius: 32; brightness: .65; opacity: 1 }
668 PropertyChanges { target: wallpaper; visible: false }
669 PropertyChanges { target: screensAndWorkspaces.showTimer; running: true }
670 },
671 State {
672 name: "stagedRightEdge"; when: root.spreadEnabled && (rightEdgeDragArea.dragging || rightEdgePushProgress > 0) && root.mode == "staged"
673 PropertyChanges {
674 target: blurLayer;
675 visible: true;
676 blurRadius: 32
677 brightness: .65
678 opacity: 1
679 }
680 PropertyChanges { target: noAppsRunningHint; visible: (root.topLevelSurfaceList.count < 1) }
681 },
682 State {
683 name: "sideStagedRightEdge"; when: root.spreadEnabled && (rightEdgeDragArea.dragging || rightEdgePushProgress > 0) && root.mode == "stagedWithSideStage"
684 extend: "stagedRightEdge"
685 PropertyChanges {
686 target: sideStage
687 opacity: priv.sideStageDelegate && priv.sideStageDelegate.x === sideStage.x ? 1 : 0
688 visible: true
689 }
690 },
691 State {
692 name: "windowedRightEdge"; when: root.spreadEnabled && (rightEdgeDragArea.dragging || rightEdgePushProgress > 0) && root.mode == "windowed"
693 PropertyChanges {
694 target: blurLayer;
695 visible: true
696 blurRadius: 32
697 brightness: .65
698 opacity: MathUtils.linearAnimation(spreadItem.rightEdgeBreakPoint, 1, 0, 1, Math.max(rightEdgeDragArea.dragging ? rightEdgeDragArea.progress : 0, rightEdgePushProgress))
699 }
700 },
701 State {
702 name: "staged"; when: root.mode === "staged"
703 PropertyChanges { target: root; focus: true }
704 PropertyChanges { target: appContainer; focus: true }
705 },
706 State {
707 name: "stagedWithSideStage"; when: root.mode === "stagedWithSideStage"
708 PropertyChanges { target: triGestureArea; enabled: priv.sideStageEnabled }
709 PropertyChanges { target: sideStage; visible: true }
710 PropertyChanges { target: root; focus: true }
711 PropertyChanges { target: appContainer; focus: true }
712 },
713 State {
714 name: "windowed"; when: root.mode === "windowed"
715 PropertyChanges { target: root; focus: true }
716 PropertyChanges { target: appContainer; focus: true }
717 }
718 ]
719 transitions: [
720 Transition {
721 from: "stagedRightEdge,sideStagedRightEdge,windowedRightEdge"; to: "spread"
722 PropertyAction { target: spreadItem; property: "highlightedIndex"; value: -1 }
723 PropertyAction { target: screensAndWorkspaces; property: "activeWorkspace"; value: WMScreen.currentWorkspace }
724 PropertyAnimation { target: blurLayer; properties: "brightness,blurRadius"; duration: priv.animationDuration }
725 },
726 Transition {
727 to: "spread"
728 PropertyAction { target: screensAndWorkspaces; property: "activeWorkspace"; value: WMScreen.currentWorkspace }
729 PropertyAction { target: spreadItem; property: "highlightedIndex"; value: appRepeater.count > 1 ? 1 : 0 }
730 PropertyAction { target: floatingFlickable; property: "contentX"; value: 0 }
731 },
732 Transition {
733 from: "spread"
734 SequentialAnimation {
735 ScriptAction {
736 script: {
737 var item = appRepeater.itemAt(Math.max(0, spreadItem.highlightedIndex));
738 if (item) {
739 if (item.stage == ApplicationInfoInterface.SideStage && !sideStage.shown) {
740 sideStage.show();
741 }
742 item.playFocusAnimation();
743 }
744 }
745 }
746 PropertyAction { target: spreadItem; property: "highlightedIndex"; value: -1 }
747 PropertyAction { target: floatingFlickable; property: "contentX"; value: 0 }
748 }
749 },
750 Transition {
751 to: "stagedRightEdge,sideStagedRightEdge"
752 PropertyAction { target: floatingFlickable; property: "contentX"; value: 0 }
753 },
754 Transition {
755 to: "stagedWithSideStage"
756 ScriptAction { script: priv.updateMainAndSideStageIndexes(); }
757 }
758
759 ]
760
761 MouseArea {
762 id: cancelSpreadMouseArea
763 anchors.fill: parent
764 enabled: false
765 onClicked: priv.goneToSpread = false
766 }
767
768 FocusScope {
769 id: appContainer
770 objectName: "appContainer"
771 anchors.fill: parent
772 focus: true
773
774 Wallpaper {
775 id: wallpaper
776 objectName: "stageBackground"
777 anchors.fill: parent
778 source: root.background
779 // Make sure it's the lowest item. Due to the left edge drag we sometimes need
780 // to put the dash at -1 and we don't want it behind the Wallpaper
781 z: -2
782 }
783
784 BlurLayer {
785 id: blurLayer
786 anchors.fill: parent
787 source: wallpaper
788 visible: false
789 }
790
791 ScreensAndWorkspaces {
792 id: screensAndWorkspaces
793 anchors { left: parent.left; top: parent.top; right: parent.right; leftMargin: root.launcherLeftMargin }
794 height: Math.max(units.gu(30), parent.height * .3)
795 background: root.background
796 visible: showAllowed
797 enabled: workspaceEnabled
798 mode: root.mode
799 availableDesktopArea: root.availableDesktopArea
800 onCloseSpread: priv.goneToSpread = false;
801 // Clicking a workspace should put it front and center
802 onActiveWorkspaceChanged: activeWorkspace.activate()
803 opacity: visible ? 1.0 : 0.0
804 Behavior on opacity {
805 NumberAnimation { duration: priv.animationDuration }
806 }
807
808 property bool showAllowed : false
809 property var showTimer: Timer {
810 running: false
811 repeat: false
812 interval: priv.animationDuration
813 onTriggered: {
814 if (!priv.goneToSpread)
815 return;
816 screensAndWorkspaces.showAllowed = root.workspaceEnabled;
817 }
818 }
819 Connections {
820 target: priv
821 onGoneToSpreadChanged: if (!priv.goneToSpread) screensAndWorkspaces.showAllowed = false
822 }
823 }
824
825 Spread {
826 id: spreadItem
827 objectName: "spreadItem"
828 anchors {
829 left: parent.left;
830 bottom: parent.bottom;
831 right: parent.right;
832 top: workspaceEnabled ? screensAndWorkspaces.bottom : parent.top;
833 }
834 leftMargin: root.availableDesktopArea.x
835 model: root.topLevelSurfaceList
836 spreadFlickable: floatingFlickable
837 z: root.topLevelSurfaceList.count
838
839 onLeaveSpread: {
840 priv.goneToSpread = false;
841 }
842
843 onCloseCurrentApp: {
844 appRepeater.itemAt(highlightedIndex).close();
845 }
846
847 FloatingFlickable {
848 id: floatingFlickable
849 objectName: "spreadFlickable"
850 anchors.fill: parent
851 enabled: false
852 contentWidth: spreadItem.spreadTotalWidth
853
854 function snap(toIndex) {
855 var delegate = appRepeater.itemAt(toIndex)
856 var targetContentX = floatingFlickable.contentWidth / spreadItem.totalItemCount * toIndex;
857 if (targetContentX - floatingFlickable.contentX > spreadItem.rightStackXPos - (spreadItem.spreadItemWidth / 2)) {
858 var offset = (spreadItem.rightStackXPos - (spreadItem.spreadItemWidth / 2)) - (targetContentX - floatingFlickable.contentX)
859 snapAnimation.to = floatingFlickable.contentX - offset;
860 snapAnimation.start();
861 } else if (targetContentX - floatingFlickable.contentX < spreadItem.leftStackXPos + units.gu(1)) {
862 var offset = (spreadItem.leftStackXPos + units.gu(1)) - (targetContentX - floatingFlickable.contentX);
863 snapAnimation.to = floatingFlickable.contentX - offset;
864 snapAnimation.start();
865 }
866 }
867 LomiriNumberAnimation {id: snapAnimation; target: floatingFlickable; property: "contentX"}
868 }
869
870 MouseArea {
871 id: hoverMouseArea
872 objectName: "hoverMouseArea"
873 anchors.fill: parent
874 propagateComposedEvents: true
875 hoverEnabled: true
876 enabled: false
877 visible: enabled
878 property bool wasTouchPress: false
879
880 property int scrollAreaWidth: width / 3
881 property bool progressiveScrollingEnabled: false
882
883 onMouseXChanged: {
884 mouse.accepted = false
885
886 if (hoverMouseArea.pressed || wasTouchPress) {
887 return;
888 }
889
890 // Find the hovered item and mark it active
891 for (var i = appRepeater.count - 1; i >= 0; i--) {
892 var appDelegate = appRepeater.itemAt(i);
893 var mapped = mapToItem(appDelegate, hoverMouseArea.mouseX, hoverMouseArea.mouseY)
894 var itemUnder = appDelegate.childAt(mapped.x, mapped.y);
895 if (itemUnder && (itemUnder.objectName === "dragArea" || itemUnder.objectName === "windowInfoItem" || itemUnder.objectName == "closeMouseArea")) {
896 spreadItem.highlightedIndex = i;
897 break;
898 }
899 }
900
901 if (floatingFlickable.contentWidth > floatingFlickable.width) {
902 var margins = floatingFlickable.width * 0.05;
903
904 if (!progressiveScrollingEnabled && mouseX < floatingFlickable.width - scrollAreaWidth) {
905 progressiveScrollingEnabled = true
906 }
907
908 // do we need to scroll?
909 if (mouseX < scrollAreaWidth + margins) {
910 var progress = Math.min(1, (scrollAreaWidth + margins - mouseX) / (scrollAreaWidth - margins));
911 var contentX = (1 - progress) * (floatingFlickable.contentWidth - floatingFlickable.width)
912 floatingFlickable.contentX = Math.max(0, Math.min(floatingFlickable.contentX, contentX))
913 }
914 if (mouseX > floatingFlickable.width - scrollAreaWidth && progressiveScrollingEnabled) {
915 var progress = Math.min(1, (mouseX - (floatingFlickable.width - scrollAreaWidth)) / (scrollAreaWidth - margins))
916 var contentX = progress * (floatingFlickable.contentWidth - floatingFlickable.width)
917 floatingFlickable.contentX = Math.min(floatingFlickable.contentWidth - floatingFlickable.width, Math.max(floatingFlickable.contentX, contentX))
918 }
919 }
920 }
921
922 onPressed: {
923 mouse.accepted = false;
924 wasTouchPress = mouse.source === Qt.MouseEventSynthesizedByQt;
925 }
926
927 onExited: wasTouchPress = false;
928 }
929 }
930
931 Label {
932 id: noAppsRunningHint
933 visible: false
934 anchors.horizontalCenter: parent.horizontalCenter
935 anchors.verticalCenter: parent.verticalCenter
936 anchors.fill: parent
937 horizontalAlignment: Qt.AlignHCenter
938 verticalAlignment: Qt.AlignVCenter
939 anchors.leftMargin: root.launcherLeftMargin
940 wrapMode: Label.WordWrap
941 fontSize: "large"
942 text: i18n.tr("No running apps")
943 color: "#FFFFFF"
944 }
945
946 Connections {
947 target: root.topLevelSurfaceList
948 function onListChanged() { priv.updateMainAndSideStageIndexes() }
949 }
950
951
952 DropArea {
953 objectName: "MainStageDropArea"
954 anchors {
955 left: parent.left
956 top: parent.top
957 bottom: parent.bottom
958 }
959 width: appContainer.width - sideStage.width
960 enabled: priv.sideStageEnabled
961
962 onDropped: {
963 drop.source.appDelegate.saveStage(ApplicationInfoInterface.MainStage);
964 drop.source.appDelegate.activate();
965 }
966 keys: "SideStage"
967 }
968
969 SideStage {
970 id: sideStage
971 objectName: "sideStage"
972 shown: false
973 height: appContainer.height
974 x: appContainer.width - width
975 visible: false
976 showHint: !priv.sideStageDelegate
977 Behavior on opacity { LomiriNumberAnimation {} }
978 z: {
979 if (!priv.mainStageItemId) return 0;
980
981 if (priv.sideStageItemId && priv.nextInStack > 0) {
982
983 // Due the order in which bindings are evaluated, this might be triggered while shuffling
984 // the list and index doesn't yet match with itemIndex (even though itemIndex: index)
985 // Let's walk the list and compare itemIndex to make sure we have the correct one.
986 var nextDelegateInStack = -1;
987 for (var i = 0; i < appRepeater.count; i++) {
988 if (appRepeater.itemAt(i).itemIndex == priv.nextInStack) {
989 nextDelegateInStack = appRepeater.itemAt(i);
990 break;
991 }
992 }
993
994 if (nextDelegateInStack.stage === ApplicationInfoInterface.MainStage) {
995 // if the next app in stack is a main stage app, put the sidestage on top of it.
996 return 2;
997 }
998 return 1;
999 }
1000
1001 return 1;
1002 }
1003
1004 onShownChanged: {
1005 if (!shown && priv.mainStageDelegate && !root.spreadShown) {
1006 priv.mainStageDelegate.activate();
1007 }
1008 }
1009
1010 DropArea {
1011 id: sideStageDropArea
1012 objectName: "SideStageDropArea"
1013 anchors.fill: parent
1014
1015 property bool dropAllowed: true
1016
1017 onEntered: {
1018 dropAllowed = drag.keys != "Disabled";
1019 }
1020 onExited: {
1021 dropAllowed = true;
1022 }
1023 onDropped: {
1024 if (drop.keys == "MainStage") {
1025 drop.source.appDelegate.saveStage(ApplicationInfoInterface.SideStage);
1026 drop.source.appDelegate.activate();
1027 }
1028 }
1029 drag {
1030 onSourceChanged: {
1031 if (!sideStageDropArea.drag.source) {
1032 dropAllowed = true;
1033 }
1034 }
1035 }
1036 }
1037 }
1038
1039 MirSurfaceItem {
1040 id: fakeDragItem
1041 property real previewScale: .5
1042 height: (screensAndWorkspaces.height - units.gu(8)) / 2
1043 // w : h = iw : ih
1044 width: implicitWidth * height / implicitHeight
1045 surfaceWidth: -1
1046 surfaceHeight: -1
1047 opacity: surface != null ? 1 : 0
1048 Behavior on opacity { LomiriNumberAnimation {} }
1049 visible: opacity > 0
1050 enabled: workspaceSwitcher
1051
1052 Drag.active: surface != null
1053 Drag.keys: ["application"]
1054
1055 z: 1000
1056 }
1057
1058 Repeater {
1059 id: appRepeater
1060 model: topLevelSurfaceList
1061 objectName: "appRepeater"
1062
1063 function indexOf(delegateItem) {
1064 for (var i = 0; i < count; i++) {
1065 if (itemAt(i) === delegateItem) {
1066 return i;
1067 }
1068 }
1069 return -1;
1070 }
1071
1072 delegate: FocusScope {
1073 id: appDelegate
1074 objectName: "appDelegate_" + model.window.id
1075 property int itemIndex: index // We need this from outside the repeater
1076 // z might be overriden in some cases by effects, but we need z ordering
1077 // to calculate occlusion detection
1078 property int normalZ: topLevelSurfaceList.count - index
1079 onNormalZChanged: {
1080 if (visuallyMaximized) {
1081 priv.updateForegroundMaximizedApp();
1082 }
1083 }
1084 z: normalZ
1085
1086 opacity: fakeDragItem.surface == model.window.surface && fakeDragItem.Drag.active ? 0 : 1
1087 Behavior on opacity { LomiriNumberAnimation {} }
1088
1089 // Set these as propertyes as they wont update otherwise
1090 property real screenOffsetX: Screen.virtualX
1091 property real screenOffsetY: Screen.virtualY
1092
1093 // Normally we want x/y where the surface thinks it is. Width/height of our delegate will
1094 // match what the actual surface size is.
1095 // Don't write to those, they will be set by states
1096 // --
1097 // Here we will also need to remove the screen offset from miral's results
1098 // as lomiri x,y will be relative to the current screen only
1099 // FIXME: when proper multiscreen lands
1100 x: model.window.position.x - clientAreaItem.x - screenOffsetX
1101 y: model.window.position.y - clientAreaItem.y - screenOffsetY
1102 width: decoratedWindow.implicitWidth
1103 height: decoratedWindow.implicitHeight
1104
1105 // requestedX/Y/width/height is what we ask the actual surface to be.
1106 // Do not write to those, they will be set by states
1107 property real requestedX: windowedX
1108 property real requestedY: windowedY
1109 property real requestedWidth: windowedWidth
1110 property real requestedHeight: windowedHeight
1111
1112 // For both windowed and staged need to tell miral what screen we are on,
1113 // so we need to add the screen offset to the position we tell miral
1114 // FIXME: when proper multiscreen lands
1115 Binding {
1116 target: model.window; property: "requestedPosition"
1117 // miral doesn't know about our window decorations. So we have to deduct them
1118 value: Qt.point(appDelegate.requestedX + appDelegate.clientAreaItem.x + screenOffsetX,
1119 appDelegate.requestedY + appDelegate.clientAreaItem.y + screenOffsetY)
1120 when: root.mode == "windowed"
1121 restoreMode: Binding.RestoreBinding
1122 }
1123 Binding {
1124 target: model.window; property: "requestedPosition"
1125 value: Qt.point(screenOffsetX, screenOffsetY)
1126 when: root.mode != "windowed"
1127 restoreMode: Binding.RestoreBinding
1128 }
1129
1130 // In those are for windowed mode. Those values basically store the window's properties
1131 // when having a floating window. If you want to move/resize a window in normal mode, this is what you want to write to.
1132 property real windowedX
1133 property real windowedY
1134 property real windowedWidth
1135 property real windowedHeight
1136
1137 // unlike windowedX/Y, this is the last known grab position before being pushed against edges/corners
1138 // when restoring, the window should return to these, not to the place where it was dropped near the edge
1139 property real restoredX
1140 property real restoredY
1141
1142 // Keeps track of the window geometry while in normal or restored state
1143 // Useful when returning from some maxmized state or when saving the geometry while maximized
1144 // FIXME: find a better solution
1145 property real normalX: 0
1146 property real normalY: 0
1147 property real normalWidth: 0
1148 property real normalHeight: 0
1149 function updateNormalGeometry() {
1150 if (appDelegate.state == "normal" || appDelegate.state == "restored") {
1151 normalX = appDelegate.requestedX;
1152 normalY = appDelegate.requestedY;
1153 normalWidth = appDelegate.width;
1154 normalHeight = appDelegate.height;
1155 }
1156 }
1157 function updateRestoredGeometry() {
1158 if (appDelegate.state == "normal" || appDelegate.state == "restored") {
1159 // save the x/y to restore to
1160 restoredX = appDelegate.x;
1161 restoredY = appDelegate.y;
1162 }
1163 }
1164
1165 Connections {
1166 target: appDelegate
1167 function onXChanged() { appDelegate.updateNormalGeometry(); }
1168 function onYChanged() { appDelegate.updateNormalGeometry(); }
1169 function onWidthChanged() { appDelegate.updateNormalGeometry(); }
1170 function onHeightChanged() { appDelegate.updateNormalGeometry(); }
1171 }
1172
1173 // True when the Stage is focusing this app and playing its own animation.
1174 // Stays true until the app is unfocused.
1175 // If it is, we don't want to play the slide in/out transition from StageMaths.
1176 // Setting it imperatively is not great, but any declarative solution hits
1177 // race conditions, causing two animations to play for one focus event.
1178 property bool inhibitSlideAnimation: false
1179
1180 Binding {
1181 target: appDelegate
1182 property: "y"
1183 value: appDelegate.requestedY -
1184 Math.min(appDelegate.requestedY - root.availableDesktopArea.y,
1185 Math.max(0, priv.virtualKeyboardHeight - (appContainer.height - (appDelegate.requestedY + appDelegate.height))))
1186 when: root.oskEnabled && appDelegate.focus && (appDelegate.state == "normal" || appDelegate.state == "restored")
1187 && root.inputMethodRect.height > 0
1188 restoreMode: Binding.RestoreBinding
1189 }
1190
1191 Behavior on x { id: xBehavior; enabled: priv.closingIndex >= 0; LomiriNumberAnimation { onRunningChanged: if (!running) priv.closingIndex = -1} }
1192
1193 Connections {
1194 target: root
1195 function onShellOrientationAngleChanged() {
1196 // at this point decoratedWindow.surfaceOrientationAngle is the old shellOrientationAngle
1197 if (appDelegate.application && appDelegate.application.rotatesWindowContents) {
1198 if (root.state == "windowed") {
1199 var angleDiff = decoratedWindow.surfaceOrientationAngle - shellOrientationAngle;
1200 angleDiff = (360 + angleDiff) % 360;
1201 if (angleDiff === 90 || angleDiff === 270) {
1202 var aux = decoratedWindow.requestedHeight;
1203 decoratedWindow.requestedHeight = decoratedWindow.requestedWidth + decoratedWindow.actualDecorationHeight;
1204 decoratedWindow.requestedWidth = aux - decoratedWindow.actualDecorationHeight;
1205 }
1206 }
1207 decoratedWindow.surfaceOrientationAngle = shellOrientationAngle;
1208 } else {
1209 decoratedWindow.surfaceOrientationAngle = 0;
1210 }
1211 }
1212 }
1213
1214 readonly property alias application: decoratedWindow.application
1215 readonly property alias minimumWidth: decoratedWindow.minimumWidth
1216 readonly property alias minimumHeight: decoratedWindow.minimumHeight
1217 readonly property alias maximumWidth: decoratedWindow.maximumWidth
1218 readonly property alias maximumHeight: decoratedWindow.maximumHeight
1219 readonly property alias widthIncrement: decoratedWindow.widthIncrement
1220 readonly property alias heightIncrement: decoratedWindow.heightIncrement
1221
1222 readonly property bool maximized: windowState === WindowStateStorage.WindowStateMaximized
1223 readonly property bool maximizedLeft: windowState === WindowStateStorage.WindowStateMaximizedLeft
1224 readonly property bool maximizedRight: windowState === WindowStateStorage.WindowStateMaximizedRight
1225 readonly property bool maximizedHorizontally: windowState === WindowStateStorage.WindowStateMaximizedHorizontally
1226 readonly property bool maximizedVertically: windowState === WindowStateStorage.WindowStateMaximizedVertically
1227 readonly property bool maximizedTopLeft: windowState === WindowStateStorage.WindowStateMaximizedTopLeft
1228 readonly property bool maximizedTopRight: windowState === WindowStateStorage.WindowStateMaximizedTopRight
1229 readonly property bool maximizedBottomLeft: windowState === WindowStateStorage.WindowStateMaximizedBottomLeft
1230 readonly property bool maximizedBottomRight: windowState === WindowStateStorage.WindowStateMaximizedBottomRight
1231 readonly property bool anyMaximized: maximized || maximizedLeft || maximizedRight || maximizedHorizontally || maximizedVertically ||
1232 maximizedTopLeft || maximizedTopRight || maximizedBottomLeft || maximizedBottomRight
1233
1234 readonly property bool minimized: windowState & WindowStateStorage.WindowStateMinimized
1235 readonly property bool fullscreen: windowState === WindowStateStorage.WindowStateFullscreen
1236
1237 readonly property bool canBeMaximized: canBeMaximizedHorizontally && canBeMaximizedVertically
1238 readonly property bool canBeMaximizedLeftRight: (maximumWidth == 0 || maximumWidth >= appContainer.width/2) &&
1239 (maximumHeight == 0 || maximumHeight >= appContainer.height)
1240 readonly property bool canBeCornerMaximized: (maximumWidth == 0 || maximumWidth >= appContainer.width/2) &&
1241 (maximumHeight == 0 || maximumHeight >= appContainer.height/2)
1242 readonly property bool canBeMaximizedHorizontally: maximumWidth == 0 || maximumWidth >= appContainer.width
1243 readonly property bool canBeMaximizedVertically: maximumHeight == 0 || maximumHeight >= appContainer.height
1244 readonly property alias orientationChangesEnabled: decoratedWindow.orientationChangesEnabled
1245
1246 // TODO drop our own windowType once Mir/Miral/Qtmir gets in sync with ours
1247 property int windowState: WindowStateStorage.WindowStateNormal
1248 property int prevWindowState: WindowStateStorage.WindowStateRestored
1249
1250 property bool animationsEnabled: true
1251 property alias title: decoratedWindow.title
1252 readonly property string appName: model.application ? model.application.name : ""
1253 property bool visuallyMaximized: false
1254 property bool visuallyMinimized: false
1255 readonly property alias windowedTransitionRunning: windowedTransition.running
1256
1257 property int stage: ApplicationInfoInterface.MainStage
1258 function saveStage(newStage) {
1259 appDelegate.stage = newStage;
1260 WindowStateStorage.saveStage(appId, newStage);
1261 priv.updateMainAndSideStageIndexes()
1262 }
1263
1264 readonly property var surface: model.window.surface
1265 readonly property var window: model.window
1266
1267 readonly property alias focusedSurface: decoratedWindow.focusedSurface
1268 readonly property bool dragging: touchControls.overlayShown ? touchControls.dragging : decoratedWindow.dragging
1269
1270 readonly property string appId: model.application.appId
1271 readonly property alias clientAreaItem: decoratedWindow.clientAreaItem
1272
1273 // It is Lomiri policy to close any window but the last one during OOM teardown
1274/*
1275 Connections {
1276 target: model.window.surface
1277 onLiveChanged: {
1278 if ((!surface.live && application && application.surfaceCount > 1) || !application)
1279 topLevelSurfaceList.removeAt(appRepeater.indexOf(appDelegate));
1280 }
1281 }
1282*/
1283
1284
1285 function activate() {
1286 if (model.window.focused) {
1287 updateQmlFocusFromMirSurfaceFocus();
1288 } else {
1289 if (surface.live) {
1290 // Activate the window since it has a surface (with a running app) backing it
1291 model.window.activate();
1292 } else {
1293 // Otherwise, cause a respawn of the app, and trigger it's refocusing as the last window
1294 topLevelSurfaceList.raiseId(model.window.id);
1295 }
1296 }
1297 }
1298 function requestMaximize() { model.window.requestState(Mir.MaximizedState); }
1299 function requestMaximizeVertically() { model.window.requestState(Mir.VertMaximizedState); }
1300 function requestMaximizeHorizontally() { model.window.requestState(Mir.HorizMaximizedState); }
1301 function requestMaximizeLeft() { model.window.requestState(Mir.MaximizedLeftState); }
1302 function requestMaximizeRight() { model.window.requestState(Mir.MaximizedRightState); }
1303 function requestMaximizeTopLeft() { model.window.requestState(Mir.MaximizedTopLeftState); }
1304 function requestMaximizeTopRight() { model.window.requestState(Mir.MaximizedTopRightState); }
1305 function requestMaximizeBottomLeft() { model.window.requestState(Mir.MaximizedBottomLeftState); }
1306 function requestMaximizeBottomRight() { model.window.requestState(Mir.MaximizedBottomRightState); }
1307 function requestMinimize() { model.window.requestState(Mir.MinimizedState); }
1308 function requestRestore() { model.window.requestState(Mir.RestoredState); }
1309
1310 function claimFocus() {
1311 if (root.state == "spread") {
1312 spreadItem.highlightedIndex = index
1313 // force pendingActivation so that when switching to staged mode, topLevelSurfaceList focus won't got to previous app ( case when apps are launched from outside )
1314 topLevelSurfaceList.pendingActivation();
1315 priv.goneToSpread = false;
1316 }
1317 if (root.mode == "stagedWithSideStage") {
1318 if (appDelegate.stage == ApplicationInfoInterface.SideStage && !sideStage.shown) {
1319 sideStage.show();
1320 }
1321 priv.updateMainAndSideStageIndexes();
1322 }
1323 appDelegate.focus = true;
1324
1325 // Don't set focusedAppDelegate (and signal mainAppChanged) unnecessarily
1326 // which can happen after getting interactive again.
1327 if (priv.focusedAppDelegate !== appDelegate)
1328 priv.focusedAppDelegate = appDelegate;
1329 }
1330
1331 function updateQmlFocusFromMirSurfaceFocus() {
1332 if (model.window.focused) {
1333 claimFocus();
1334 decoratedWindow.focus = true;
1335 }
1336 }
1337
1338 WindowStateSaver {
1339 id: windowStateSaver
1340 target: appDelegate
1341 screenWidth: appContainer.width
1342 screenHeight: appContainer.height
1343 leftMargin: root.availableDesktopArea.x
1344 minimumY: root.availableDesktopArea.y
1345 }
1346
1347 Connections {
1348 target: model.window
1349 function onFocusedChanged() {
1350 updateQmlFocusFromMirSurfaceFocus();
1351 if (!model.window.focused) {
1352 inhibitSlideAnimation = false;
1353 }
1354 }
1355 function onFocusRequested() {
1356 appDelegate.activate();
1357 }
1358 function onStateChanged(value) {
1359 if (value == Mir.MinimizedState) {
1360 appDelegate.minimize();
1361 } else if (value == Mir.MaximizedState) {
1362 appDelegate.maximize();
1363 } else if (value == Mir.VertMaximizedState) {
1364 appDelegate.maximizeVertically();
1365 } else if (value == Mir.HorizMaximizedState) {
1366 appDelegate.maximizeHorizontally();
1367 } else if (value == Mir.MaximizedLeftState) {
1368 appDelegate.maximizeLeft();
1369 } else if (value == Mir.MaximizedRightState) {
1370 appDelegate.maximizeRight();
1371 } else if (value == Mir.MaximizedTopLeftState) {
1372 appDelegate.maximizeTopLeft();
1373 } else if (value == Mir.MaximizedTopRightState) {
1374 appDelegate.maximizeTopRight();
1375 } else if (value == Mir.MaximizedBottomLeftState) {
1376 appDelegate.maximizeBottomLeft();
1377 } else if (value == Mir.MaximizedBottomRightState) {
1378 appDelegate.maximizeBottomRight();
1379 } else if (value == Mir.RestoredState) {
1380 if (appDelegate.fullscreen && appDelegate.prevWindowState != WindowStateStorage.WindowStateRestored
1381 && appDelegate.prevWindowState != WindowStateStorage.WindowStateNormal) {
1382 model.window.requestState(WindowStateStorage.toMirState(appDelegate.prevWindowState));
1383 } else {
1384 appDelegate.restore();
1385 }
1386 } else if (value == Mir.FullscreenState) {
1387 appDelegate.prevWindowState = appDelegate.windowState;
1388 appDelegate.windowState = WindowStateStorage.WindowStateFullscreen;
1389 }
1390 }
1391 }
1392
1393 readonly property bool windowReady: clientAreaItem.surfaceInitialized
1394 onWindowReadyChanged: {
1395 if (windowReady) {
1396 var loadedMirState = WindowStateStorage.toMirState(windowStateSaver.loadedState);
1397 var state = loadedMirState;
1398
1399 if (window.state == Mir.FullscreenState) {
1400 // If the app is fullscreen at startup, we should not use saved state
1401 // Example of why: if you open game that only requests fullscreen at
1402 // Statup, this will automaticly be set to "restored state" since
1403 // thats the default value of stateStorage, this will result in the app
1404 // having the "restored state" as it will not make a fullscreen
1405 // call after the app has started.
1406 console.log("Initial window state is fullscreen, not using saved state.");
1407 state = window.state;
1408 } else if (loadedMirState == Mir.FullscreenState) {
1409 // If saved state is fullscreen, we should use app initial state
1410 // Example of why: if you open browser with youtube video at fullscreen
1411 // and close this app, it will be fullscreen next time you open the app.
1412 console.log("Saved window state is fullscreen, using initial window state");
1413 state = window.state;
1414 }
1415
1416 // need to apply the shell chrome policy on top the saved window state
1417 var policy;
1418 if (root.mode == "windowed") {
1419 policy = windowedFullscreenPolicy;
1420 } else {
1421 policy = stagedFullscreenPolicy
1422 }
1423 window.requestState(policy.applyPolicy(state, surface.shellChrome));
1424 }
1425 }
1426
1427 Component.onCompleted: {
1428 if (application && application.rotatesWindowContents) {
1429 decoratedWindow.surfaceOrientationAngle = shellOrientationAngle;
1430 } else {
1431 decoratedWindow.surfaceOrientationAngle = 0;
1432 }
1433
1434 // First, cascade the newly created window, relative to the currently/old focused window.
1435 windowedX = priv.focusedAppDelegate ? priv.focusedAppDelegate.windowedX + units.gu(3) : (normalZ - 1) * units.gu(3)
1436 windowedY = priv.focusedAppDelegate ? priv.focusedAppDelegate.windowedY + units.gu(3) : normalZ * units.gu(3)
1437 // Now load any saved state. This needs to happen *after* the cascading!
1438 windowStateSaver.load();
1439
1440 updateQmlFocusFromMirSurfaceFocus();
1441
1442 refreshStage();
1443 _constructing = false;
1444 }
1445 Component.onDestruction: {
1446 windowStateSaver.save();
1447
1448 if (!root.parent) {
1449 // This stage is about to be destroyed. Don't mess up with the model at this point
1450 return;
1451 }
1452
1453 if (visuallyMaximized) {
1454 priv.updateForegroundMaximizedApp();
1455 }
1456 }
1457
1458 onVisuallyMaximizedChanged: priv.updateForegroundMaximizedApp()
1459
1460 property bool _constructing: true;
1461 onStageChanged: {
1462 if (!_constructing) {
1463 priv.updateMainAndSideStageIndexes();
1464 }
1465 }
1466
1467 visible: (
1468 !visuallyMinimized
1469 && !greeter.fullyShown
1470 && (priv.foregroundMaximizedAppDelegate === null || priv.foregroundMaximizedAppDelegate.normalZ <= z)
1471 )
1472 || appDelegate.fullscreen
1473 || focusAnimation.running || rightEdgeFocusAnimation.running || hidingAnimation.running
1474
1475 function close() {
1476 model.window.close();
1477 }
1478
1479 function maximize(animated) {
1480 animationsEnabled = (animated === undefined) || animated;
1481 windowState = WindowStateStorage.WindowStateMaximized;
1482 }
1483 function maximizeLeft(animated) {
1484 animationsEnabled = (animated === undefined) || animated;
1485 windowState = WindowStateStorage.WindowStateMaximizedLeft;
1486 }
1487 function maximizeRight(animated) {
1488 animationsEnabled = (animated === undefined) || animated;
1489 windowState = WindowStateStorage.WindowStateMaximizedRight;
1490 }
1491 function maximizeHorizontally(animated) {
1492 animationsEnabled = (animated === undefined) || animated;
1493 windowState = WindowStateStorage.WindowStateMaximizedHorizontally;
1494 }
1495 function maximizeVertically(animated) {
1496 animationsEnabled = (animated === undefined) || animated;
1497 windowState = WindowStateStorage.WindowStateMaximizedVertically;
1498 }
1499 function maximizeTopLeft(animated) {
1500 animationsEnabled = (animated === undefined) || animated;
1501 windowState = WindowStateStorage.WindowStateMaximizedTopLeft;
1502 }
1503 function maximizeTopRight(animated) {
1504 animationsEnabled = (animated === undefined) || animated;
1505 windowState = WindowStateStorage.WindowStateMaximizedTopRight;
1506 }
1507 function maximizeBottomLeft(animated) {
1508 animationsEnabled = (animated === undefined) || animated;
1509 windowState = WindowStateStorage.WindowStateMaximizedBottomLeft;
1510 }
1511 function maximizeBottomRight(animated) {
1512 animationsEnabled = (animated === undefined) || animated;
1513 windowState = WindowStateStorage.WindowStateMaximizedBottomRight;
1514 }
1515 function minimize(animated) {
1516 animationsEnabled = (animated === undefined) || animated;
1517 windowState |= WindowStateStorage.WindowStateMinimized; // add the minimized bit
1518 }
1519 function restore(animated,state) {
1520 animationsEnabled = (animated === undefined) || animated;
1521 windowState = state || WindowStateStorage.WindowStateRestored;
1522 windowState &= ~WindowStateStorage.WindowStateMinimized; // clear the minimized bit
1523 prevWindowState = windowState;
1524 }
1525
1526 function playFocusAnimation() {
1527 if (state == "stagedRightEdge") {
1528 // TODO: Can we drop this if and find something that always works?
1529 if (root.mode == "staged") {
1530 rightEdgeFocusAnimation.targetX = 0
1531 rightEdgeFocusAnimation.start()
1532 } else if (root.mode == "stagedWithSideStage") {
1533 rightEdgeFocusAnimation.targetX = appDelegate.stage == ApplicationInfoInterface.SideStage ? sideStage.x : 0
1534 rightEdgeFocusAnimation.start()
1535 }
1536 } else {
1537 focusAnimation.start()
1538 }
1539 }
1540 function playHidingAnimation() {
1541 if (state != "windowedRightEdge") {
1542 hidingAnimation.start()
1543 }
1544 }
1545
1546 function refreshStage() {
1547 var newStage = ApplicationInfoInterface.MainStage;
1548 if (priv.sideStageEnabled) { // we're in lanscape rotation.
1549 if (application && application.supportedOrientations & (Qt.PortraitOrientation|Qt.InvertedPortraitOrientation)) {
1550 var defaultStage = ApplicationInfoInterface.SideStage; // if application supports portrait, it defaults to sidestage.
1551 if (application.supportedOrientations & (Qt.LandscapeOrientation|Qt.InvertedLandscapeOrientation)) {
1552 // if it supports lanscape, it defaults to mainstage.
1553 defaultStage = ApplicationInfoInterface.MainStage;
1554 }
1555 newStage = WindowStateStorage.getStage(application.appId, defaultStage);
1556 }
1557 }
1558
1559 stage = newStage;
1560 if (focus && stage == ApplicationInfoInterface.SideStage && !sideStage.shown) {
1561 sideStage.show();
1562 }
1563 }
1564
1565 LomiriNumberAnimation {
1566 id: focusAnimation
1567 target: appDelegate
1568 property: "scale"
1569 from: 0.98
1570 to: 1
1571 duration: LomiriAnimation.SnapDuration
1572 onStarted: {
1573 topLevelSurfaceList.pendingActivation();
1574 topLevelSurfaceList.raiseId(model.window.id);
1575 }
1576 onStopped: {
1577 appDelegate.activate();
1578 }
1579 }
1580 ParallelAnimation {
1581 id: rightEdgeFocusAnimation
1582 property int targetX: 0
1583 LomiriNumberAnimation { target: appDelegate; properties: "x"; to: rightEdgeFocusAnimation.targetX; duration: priv.animationDuration }
1584 LomiriNumberAnimation { target: decoratedWindow; properties: "angle"; to: 0; duration: priv.animationDuration }
1585 LomiriNumberAnimation { target: decoratedWindow; properties: "itemScale"; to: 1; duration: priv.animationDuration }
1586 onStarted: {
1587 topLevelSurfaceList.pendingActivation();
1588 inhibitSlideAnimation = true;
1589 }
1590 onStopped: {
1591 appDelegate.activate();
1592 }
1593 }
1594 ParallelAnimation {
1595 id: hidingAnimation
1596 LomiriNumberAnimation { target: appDelegate; property: "opacity"; to: 0; duration: priv.animationDuration }
1597 onStopped: appDelegate.opacity = 1
1598 }
1599
1600 SpreadMaths {
1601 id: spreadMaths
1602 spread: spreadItem
1603 itemIndex: index
1604 flickable: floatingFlickable
1605 }
1606 StageMaths {
1607 id: stageMaths
1608 sceneWidth: root.width
1609 stage: appDelegate.stage
1610 thisDelegate: appDelegate
1611 mainStageDelegate: priv.mainStageDelegate
1612 sideStageDelegate: priv.sideStageDelegate
1613 sideStageWidth: sideStage.panelWidth
1614 sideStageHandleWidth: sideStage.handleWidth
1615 sideStageX: sideStage.x
1616 itemIndex: appDelegate.itemIndex
1617 nextInStack: priv.nextInStack
1618 animationDuration: priv.animationDuration
1619 }
1620
1621 StagedRightEdgeMaths {
1622 id: stagedRightEdgeMaths
1623 sceneWidth: root.availableDesktopArea.width
1624 sceneHeight: appContainer.height
1625 isMainStageApp: priv.mainStageDelegate == appDelegate
1626 isSideStageApp: priv.sideStageDelegate == appDelegate
1627 sideStageWidth: sideStage.width
1628 sideStageOpen: sideStage.shown
1629 itemIndex: index
1630 nextInStack: priv.nextInStack
1631 progress: 0
1632 targetHeight: spreadItem.stackHeight
1633 targetX: spreadMaths.targetX
1634 startY: appDelegate.fullscreen ? 0 : root.availableDesktopArea.y
1635 targetY: spreadMaths.targetY
1636 targetAngle: spreadMaths.targetAngle
1637 targetScale: spreadMaths.targetScale
1638 shuffledZ: stageMaths.itemZ
1639 breakPoint: spreadItem.rightEdgeBreakPoint
1640 }
1641
1642 WindowedRightEdgeMaths {
1643 id: windowedRightEdgeMaths
1644 itemIndex: index
1645 startWidth: appDelegate.requestedWidth
1646 startHeight: appDelegate.requestedHeight
1647 targetHeight: spreadItem.stackHeight
1648 targetX: spreadMaths.targetX
1649 targetY: spreadMaths.targetY
1650 normalZ: appDelegate.normalZ
1651 targetAngle: spreadMaths.targetAngle
1652 targetScale: spreadMaths.targetScale
1653 breakPoint: spreadItem.rightEdgeBreakPoint
1654 }
1655
1656 states: [
1657 State {
1658 name: "spread"; when: root.state == "spread"
1659 StateChangeScript { script: { decoratedWindow.cancelDrag(); } }
1660 PropertyChanges {
1661 target: decoratedWindow;
1662 showDecoration: false;
1663 angle: spreadMaths.targetAngle
1664 itemScale: spreadMaths.targetScale
1665 scaleToPreviewSize: spreadItem.stackHeight
1666 scaleToPreviewProgress: 1
1667 hasDecoration: root.mode === "windowed"
1668 shadowOpacity: spreadMaths.shadowOpacity
1669 showHighlight: spreadItem.highlightedIndex === index
1670 darkening: spreadItem.highlightedIndex >= 0
1671 anchors.topMargin: dragArea.distance
1672 }
1673 PropertyChanges {
1674 target: appDelegate
1675 x: spreadMaths.targetX
1676 y: spreadMaths.targetY
1677 z: index
1678 height: spreadItem.spreadItemHeight
1679 visible: spreadMaths.itemVisible
1680 }
1681 PropertyChanges { target: dragArea; enabled: true }
1682 PropertyChanges { target: windowInfoItem; opacity: spreadMaths.tileInfoOpacity; visible: spreadMaths.itemVisible }
1683 PropertyChanges { target: touchControls; enabled: false }
1684 },
1685 State {
1686 name: "stagedRightEdge"
1687 when: (root.mode == "staged" || root.mode == "stagedWithSideStage") && (root.state == "sideStagedRightEdge" || root.state == "stagedRightEdge" || rightEdgeFocusAnimation.running || hidingAnimation.running)
1688 PropertyChanges {
1689 target: stagedRightEdgeMaths
1690 progress: Math.max(rightEdgePushProgress, rightEdgeDragArea.draggedProgress)
1691 }
1692 PropertyChanges {
1693 target: appDelegate
1694 x: stagedRightEdgeMaths.animatedX
1695 y: stagedRightEdgeMaths.animatedY
1696 z: stagedRightEdgeMaths.animatedZ
1697 height: stagedRightEdgeMaths.animatedHeight
1698 visible: appDelegate.x < root.width
1699 }
1700 PropertyChanges {
1701 target: decoratedWindow
1702 hasDecoration: false
1703 angle: stagedRightEdgeMaths.animatedAngle
1704 itemScale: stagedRightEdgeMaths.animatedScale
1705 scaleToPreviewSize: spreadItem.stackHeight
1706 scaleToPreviewProgress: stagedRightEdgeMaths.scaleToPreviewProgress
1707 shadowOpacity: .3
1708 }
1709 // make sure it's visible but transparent so it fades in when we transition to spread
1710 PropertyChanges { target: windowInfoItem; opacity: 0; visible: true }
1711 },
1712 State {
1713 name: "windowedRightEdge"
1714 when: root.mode == "windowed" && (root.state == "windowedRightEdge" || rightEdgeFocusAnimation.running || hidingAnimation.running || rightEdgePushProgress > 0)
1715 PropertyChanges {
1716 target: windowedRightEdgeMaths
1717 swipeProgress: rightEdgeDragArea.dragging ? rightEdgeDragArea.progress : 0
1718 pushProgress: rightEdgePushProgress
1719 }
1720 PropertyChanges {
1721 target: appDelegate
1722 x: windowedRightEdgeMaths.animatedX
1723 y: windowedRightEdgeMaths.animatedY
1724 z: windowedRightEdgeMaths.animatedZ
1725 height: stagedRightEdgeMaths.animatedHeight
1726 }
1727 PropertyChanges {
1728 target: decoratedWindow
1729 showDecoration: windowedRightEdgeMaths.decorationHeight
1730 angle: windowedRightEdgeMaths.animatedAngle
1731 itemScale: windowedRightEdgeMaths.animatedScale
1732 scaleToPreviewSize: spreadItem.stackHeight
1733 scaleToPreviewProgress: windowedRightEdgeMaths.scaleToPreviewProgress
1734 shadowOpacity: .3
1735 }
1736 PropertyChanges {
1737 target: opacityEffect;
1738 opacityValue: windowedRightEdgeMaths.opacityMask
1739 sourceItem: windowedRightEdgeMaths.opacityMask < 1 ? decoratedWindow : null
1740 }
1741 },
1742 State {
1743 name: "staged"; when: root.state == "staged"
1744 PropertyChanges {
1745 target: appDelegate
1746 x: stageMaths.itemX
1747 y: root.availableDesktopArea.y
1748 visuallyMaximized: true
1749 visible: appDelegate.x < root.width
1750 }
1751 PropertyChanges {
1752 target: appDelegate
1753 requestedWidth: appContainer.width
1754 requestedHeight: root.availableDesktopArea.height
1755 restoreEntryValues: false
1756 }
1757 PropertyChanges {
1758 target: decoratedWindow
1759 hasDecoration: false
1760 }
1761 PropertyChanges {
1762 target: resizeArea
1763 enabled: false
1764 }
1765 PropertyChanges {
1766 target: stageMaths
1767 animateX: !focusAnimation.running && !rightEdgeFocusAnimation.running && itemIndex !== spreadItem.highlightedIndex && !inhibitSlideAnimation
1768 }
1769 PropertyChanges {
1770 target: appDelegate.window
1771 allowClientResize: false
1772 }
1773 },
1774 State {
1775 name: "stagedWithSideStage"; when: root.state == "stagedWithSideStage"
1776 PropertyChanges {
1777 target: stageMaths
1778 itemIndex: index
1779 }
1780 PropertyChanges {
1781 target: appDelegate
1782 x: stageMaths.itemX
1783 y: root.availableDesktopArea.y
1784 z: stageMaths.itemZ
1785 visuallyMaximized: true
1786 visible: appDelegate.x < root.width
1787 }
1788 PropertyChanges {
1789 target: appDelegate
1790 requestedWidth: stageMaths.itemWidth
1791 requestedHeight: root.availableDesktopArea.height
1792 restoreEntryValues: false
1793 }
1794 PropertyChanges {
1795 target: decoratedWindow
1796 hasDecoration: false
1797 }
1798 PropertyChanges {
1799 target: resizeArea
1800 enabled: false
1801 }
1802 PropertyChanges {
1803 target: appDelegate.window
1804 allowClientResize: false
1805 }
1806 },
1807 State {
1808 name: "maximized"; when: appDelegate.maximized && !appDelegate.minimized
1809 PropertyChanges {
1810 target: appDelegate;
1811 requestedX: root.availableDesktopArea.x;
1812 requestedY: 0;
1813 visuallyMinimized: false;
1814 visuallyMaximized: true
1815 }
1816 PropertyChanges {
1817 target: appDelegate
1818 requestedWidth: root.availableDesktopArea.width;
1819 requestedHeight: appContainer.height;
1820 restoreEntryValues: false
1821 }
1822 PropertyChanges { target: touchControls; enabled: true }
1823 PropertyChanges { target: decoratedWindow; windowControlButtonsVisible: false }
1824 },
1825 State {
1826 name: "fullscreen"; when: appDelegate.fullscreen && !appDelegate.minimized
1827 PropertyChanges {
1828 target: appDelegate;
1829 requestedX: 0
1830 requestedY: 0
1831 }
1832 PropertyChanges {
1833 target: appDelegate
1834 requestedWidth: appContainer.width
1835 requestedHeight: appContainer.height
1836 restoreEntryValues: false
1837 }
1838 PropertyChanges { target: decoratedWindow; hasDecoration: false }
1839 },
1840 State {
1841 name: "normal";
1842 when: appDelegate.windowState == WindowStateStorage.WindowStateNormal
1843 PropertyChanges {
1844 target: appDelegate
1845 visuallyMinimized: false
1846 }
1847 PropertyChanges { target: touchControls; enabled: true }
1848 PropertyChanges { target: resizeArea; enabled: true }
1849 PropertyChanges { target: decoratedWindow; shadowOpacity: .3; windowControlButtonsVisible: true}
1850 PropertyChanges {
1851 target: appDelegate
1852 requestedWidth: windowedWidth
1853 requestedHeight: windowedHeight
1854 restoreEntryValues: false
1855 }
1856 },
1857 State {
1858 name: "restored";
1859 when: appDelegate.windowState == WindowStateStorage.WindowStateRestored
1860 extend: "normal"
1861 PropertyChanges {
1862 restoreEntryValues: false
1863 target: appDelegate;
1864 windowedX: restoredX;
1865 windowedY: restoredY;
1866 }
1867 },
1868 State {
1869 name: "maximizedLeft"; when: appDelegate.maximizedLeft && !appDelegate.minimized
1870 extend: "normal"
1871 PropertyChanges {
1872 target: appDelegate
1873 windowedX: root.availableDesktopArea.x
1874 windowedY: root.availableDesktopArea.y
1875 windowedWidth: root.availableDesktopArea.width / 2
1876 windowedHeight: root.availableDesktopArea.height
1877 }
1878 },
1879 State {
1880 name: "maximizedRight"; when: appDelegate.maximizedRight && !appDelegate.minimized
1881 extend: "maximizedLeft"
1882 PropertyChanges {
1883 target: appDelegate;
1884 windowedX: root.availableDesktopArea.x + (root.availableDesktopArea.width / 2)
1885 }
1886 },
1887 State {
1888 name: "maximizedTopLeft"; when: appDelegate.maximizedTopLeft && !appDelegate.minimized
1889 extend: "normal"
1890 PropertyChanges {
1891 target: appDelegate
1892 windowedX: root.availableDesktopArea.x
1893 windowedY: root.availableDesktopArea.y
1894 windowedWidth: root.availableDesktopArea.width / 2
1895 windowedHeight: root.availableDesktopArea.height / 2
1896 }
1897 },
1898 State {
1899 name: "maximizedTopRight"; when: appDelegate.maximizedTopRight && !appDelegate.minimized
1900 extend: "maximizedTopLeft"
1901 PropertyChanges {
1902 target: appDelegate
1903 windowedX: root.availableDesktopArea.x + (root.availableDesktopArea.width / 2)
1904 }
1905 },
1906 State {
1907 name: "maximizedBottomLeft"; when: appDelegate.maximizedBottomLeft && !appDelegate.minimized
1908 extend: "normal"
1909 PropertyChanges {
1910 target: appDelegate
1911 windowedX: root.availableDesktopArea.x
1912 windowedY: root.availableDesktopArea.y + (root.availableDesktopArea.height / 2)
1913 windowedWidth: root.availableDesktopArea.width / 2
1914 windowedHeight: root.availableDesktopArea.height / 2
1915 }
1916 },
1917 State {
1918 name: "maximizedBottomRight"; when: appDelegate.maximizedBottomRight && !appDelegate.minimized
1919 extend: "maximizedBottomLeft"
1920 PropertyChanges {
1921 target: appDelegate
1922 windowedX: root.availableDesktopArea.x + (root.availableDesktopArea.width / 2)
1923 }
1924 },
1925 State {
1926 name: "maximizedHorizontally"; when: appDelegate.maximizedHorizontally && !appDelegate.minimized
1927 extend: "normal"
1928 PropertyChanges {
1929 target: appDelegate
1930 windowedX: root.availableDesktopArea.x; windowedY: windowedY
1931 windowedWidth: root.availableDesktopArea.width; windowedHeight: windowedHeight
1932 }
1933 },
1934 State {
1935 name: "maximizedVertically"; when: appDelegate.maximizedVertically && !appDelegate.minimized
1936 extend: "normal"
1937 PropertyChanges {
1938 target: appDelegate
1939 windowedX: windowedX; windowedY: root.availableDesktopArea.y
1940 windowedWidth: windowedWidth; windowedHeight: root.availableDesktopArea.height
1941 }
1942 },
1943 State {
1944 name: "minimized"; when: appDelegate.minimized
1945 PropertyChanges {
1946 target: appDelegate
1947 scale: units.gu(5) / appDelegate.width
1948 opacity: 0;
1949 visuallyMinimized: true
1950 visuallyMaximized: false
1951 x: -appDelegate.width / 2
1952 y: root.height / 2
1953 }
1954 }
1955 ]
1956
1957 transitions: [
1958
1959 // These two animate applications into position from Staged to Desktop and back
1960 Transition {
1961 from: "staged,stagedWithSideStage"
1962 to: "normal,restored,maximized,maximizedHorizontally,maximizedVertically,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedBottomLeft,maximizedTopRight,maximizedBottomRight"
1963 enabled: appDelegate.animationsEnabled
1964 PropertyAction { target: appDelegate; properties: "visuallyMinimized,visuallyMaximized" }
1965 LomiriNumberAnimation { target: appDelegate; properties: "x,y,requestedX,requestedY,opacity,requestedWidth,requestedHeight,scale"; duration: priv.animationDuration }
1966 },
1967 Transition {
1968 from: "normal,restored,maximized,maximizedHorizontally,maximizedVertically,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedBottomLeft,maximizedTopRight,maximizedBottomRight"
1969 to: "staged,stagedWithSideStage"
1970 LomiriNumberAnimation { target: appDelegate; properties: "x,y,requestedX,requestedY,requestedWidth,requestedHeight"; duration: priv.animationDuration}
1971 },
1972
1973 Transition {
1974 from: "normal,restored,maximized,maximizedHorizontally,maximizedVertically,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedBottomLeft,maximizedTopRight,maximizedBottomRight,staged,stagedWithSideStage,windowedRightEdge,stagedRightEdge";
1975 to: "spread"
1976 // DecoratedWindow wants the scaleToPreviewSize set before enabling scaleToPreview
1977 PropertyAction { target: appDelegate; properties: "z,visible" }
1978 PropertyAction { target: decoratedWindow; property: "scaleToPreviewSize" }
1979 LomiriNumberAnimation { target: appDelegate; properties: "x,y,height"; duration: priv.animationDuration }
1980 LomiriNumberAnimation { target: decoratedWindow; properties: "width,height,itemScale,angle,scaleToPreviewProgress"; duration: priv.animationDuration }
1981 LomiriNumberAnimation { target: windowInfoItem; properties: "opacity"; duration: priv.animationDuration }
1982 },
1983 Transition {
1984 from: "normal,staged"; to: "stagedWithSideStage"
1985 LomiriNumberAnimation { target: appDelegate; properties: "x,y,requestedWidth,requestedHeight"; duration: priv.animationDuration }
1986 },
1987 Transition {
1988 to: "windowedRightEdge"
1989 ScriptAction {
1990 script: {
1991 windowedRightEdgeMaths.startX = appDelegate.requestedX
1992 windowedRightEdgeMaths.startY = appDelegate.requestedY
1993
1994 if (index == 1) {
1995 var thisRect = { x: appDelegate.windowedX, y: appDelegate.windowedY, width: appDelegate.requestedWidth, height: appDelegate.requestedHeight }
1996 var otherDelegate = appRepeater.itemAt(0);
1997 var otherRect = { x: otherDelegate.windowedX, y: otherDelegate.windowedY, width: otherDelegate.requestedWidth, height: otherDelegate.requestedHeight }
1998 var intersectionRect = MathUtils.intersectionRect(thisRect, otherRect)
1999 var mappedInterSectionRect = appDelegate.mapFromItem(root, intersectionRect.x, intersectionRect.y)
2000 opacityEffect.maskX = mappedInterSectionRect.x
2001 opacityEffect.maskY = mappedInterSectionRect.y
2002 opacityEffect.maskWidth = intersectionRect.width
2003 opacityEffect.maskHeight = intersectionRect.height
2004 }
2005 }
2006 }
2007 },
2008 Transition {
2009 from: "stagedRightEdge"; to: "staged"
2010 enabled: rightEdgeDragArea.cancelled // only transition back to state if the gesture was cancelled, in the other cases we play the focusAnimations.
2011 SequentialAnimation {
2012 ParallelAnimation {
2013 LomiriNumberAnimation { target: appDelegate; properties: "x,y,height,width,scale"; duration: priv.animationDuration }
2014 LomiriNumberAnimation { target: decoratedWindow; properties: "width,height,itemScale,angle,scaleToPreviewProgress"; duration: priv.animationDuration }
2015 }
2016 // We need to release scaleToPreviewSize at last
2017 PropertyAction { target: decoratedWindow; property: "scaleToPreviewSize" }
2018 PropertyAction { target: appDelegate; property: "visible" }
2019 }
2020 },
2021 Transition {
2022 from: ",normal,restored,maximized,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedTopRight,maximizedBottomLeft,maximizedBottomRight,maximizedHorizontally,maximizedVertically,fullscreen"
2023 to: "minimized"
2024 SequentialAnimation {
2025 ScriptAction { script: { fakeRectangle.stop(); } }
2026 PropertyAction { target: appDelegate; property: "visuallyMaximized" }
2027 PropertyAction { target: appDelegate; property: "visuallyMinimized" }
2028 LomiriNumberAnimation { target: appDelegate; properties: "x,y,scale,opacity"; duration: priv.animationDuration }
2029 PropertyAction { target: appDelegate; property: "visuallyMinimized" }
2030 }
2031 },
2032 Transition {
2033 from: "minimized"
2034 to: ",normal,restored,maximized,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedTopRight,maximizedBottomLeft,maximizedBottomRight,maximizedHorizontally,maximizedVertically,fullscreen"
2035 SequentialAnimation {
2036 PropertyAction { target: appDelegate; property: "visuallyMinimized,z" }
2037 ParallelAnimation {
2038 LomiriNumberAnimation { target: appDelegate; properties: "x"; from: -appDelegate.width / 2; duration: priv.animationDuration }
2039 LomiriNumberAnimation { target: appDelegate; properties: "y,opacity"; duration: priv.animationDuration }
2040 LomiriNumberAnimation { target: appDelegate; properties: "scale"; from: 0; duration: priv.animationDuration }
2041 }
2042 PropertyAction { target: appDelegate; property: "visuallyMaximized" }
2043 }
2044 },
2045 Transition {
2046 id: windowedTransition
2047 from: ",normal,restored,maximized,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedTopRight,maximizedBottomLeft,maximizedBottomRight,maximizedHorizontally,maximizedVertically,fullscreen,minimized"
2048 to: ",normal,restored,maximized,maximizedLeft,maximizedRight,maximizedTopLeft,maximizedTopRight,maximizedBottomLeft,maximizedBottomRight,maximizedHorizontally,maximizedVertically,fullscreen"
2049 enabled: appDelegate.animationsEnabled
2050 SequentialAnimation {
2051 ScriptAction { script: {
2052 if (appDelegate.visuallyMaximized) visuallyMaximized = false; // maximized before -> going to restored
2053 }
2054 }
2055 PropertyAction { target: appDelegate; property: "visuallyMinimized" }
2056 LomiriNumberAnimation { target: appDelegate; properties: "requestedX,requestedY,windowedX,windowedY,opacity,scale,requestedWidth,requestedHeight,windowedWidth,windowedHeight";
2057 duration: priv.animationDuration }
2058 ScriptAction { script: {
2059 fakeRectangle.stop();
2060 appDelegate.visuallyMaximized = appDelegate.maximized; // reflect the target state
2061 }
2062 }
2063 }
2064 }
2065 ]
2066
2067 Binding {
2068 target: panelState
2069 property: "decorationsAlwaysVisible"
2070 value: appDelegate && appDelegate.maximized && touchControls.overlayShown
2071 restoreMode: Binding.RestoreBinding
2072 }
2073
2074 WindowResizeArea {
2075 id: resizeArea
2076 objectName: "windowResizeArea"
2077
2078 anchors.fill: appDelegate
2079
2080 // workaround so that it chooses the correct resize borders when you drag from a corner ResizeGrip
2081 anchors.margins: touchControls.overlayShown ? borderThickness/2 : -borderThickness
2082
2083 target: appDelegate
2084 boundsItem: root.availableDesktopArea
2085 minWidth: units.gu(10)
2086 minHeight: units.gu(10)
2087 borderThickness: units.gu(2)
2088 enabled: false
2089 visible: enabled
2090 readyToAssesBounds: !appDelegate._constructing
2091
2092 onPressed: {
2093 appDelegate.activate();
2094 }
2095 }
2096
2097 DecoratedWindow {
2098 id: decoratedWindow
2099 objectName: "decoratedWindow"
2100 anchors.left: appDelegate.left
2101 anchors.top: appDelegate.top
2102 stage: root
2103 application: model.application
2104 surface: model.window.surface
2105 active: model.window.focused
2106 focus: true
2107 interactive: root.interactive
2108 showDecoration: 1
2109 decorationHeight: priv.windowDecorationHeight
2110 maximizeButtonShown: appDelegate.canBeMaximized
2111 overlayShown: touchControls.overlayShown
2112 width: implicitWidth
2113 height: implicitHeight
2114 highlightSize: windowInfoItem.iconMargin / 2
2115 boundsItem: root.availableDesktopArea
2116 panelState: root.panelState
2117 altDragEnabled: root.mode == "windowed"
2118 lightMode: root.lightMode
2119 clipSurface: root.mode === "windowed"
2120
2121 requestedWidth: appDelegate.requestedWidth
2122 requestedHeight: appDelegate.requestedHeight
2123
2124 onCloseClicked: { appDelegate.close(); }
2125 onMaximizeClicked: {
2126 if (appDelegate.canBeMaximized) {
2127 appDelegate.anyMaximized ? appDelegate.requestRestore() : appDelegate.requestMaximize();
2128 }
2129 }
2130 onMaximizeHorizontallyClicked: {
2131 if (appDelegate.canBeMaximizedHorizontally) {
2132 appDelegate.maximizedHorizontally ? appDelegate.requestRestore() : appDelegate.requestMaximizeHorizontally()
2133 }
2134 }
2135 onMaximizeVerticallyClicked: {
2136 if (appDelegate.canBeMaximizedVertically) {
2137 appDelegate.maximizedVertically ? appDelegate.requestRestore() : appDelegate.requestMaximizeVertically()
2138 }
2139 }
2140 onMinimizeClicked: { appDelegate.requestMinimize(); }
2141 onDecorationPressed: { appDelegate.activate(); }
2142 onDecorationReleased: fakeRectangle.visible ? fakeRectangle.commit() : appDelegate.updateRestoredGeometry()
2143
2144 property real angle: 0
2145 Behavior on angle { enabled: priv.closingIndex >= 0; LomiriNumberAnimation {} }
2146 property real itemScale: 1
2147 Behavior on itemScale { enabled: priv.closingIndex >= 0; LomiriNumberAnimation {} }
2148
2149 transform: [
2150 Scale {
2151 origin.x: 0
2152 origin.y: decoratedWindow.implicitHeight / 2
2153 xScale: decoratedWindow.itemScale
2154 yScale: decoratedWindow.itemScale
2155 },
2156 Rotation {
2157 origin { x: 0; y: (decoratedWindow.height / 2) }
2158 axis { x: 0; y: 1; z: 0 }
2159 angle: decoratedWindow.angle
2160 }
2161 ]
2162 }
2163
2164 OpacityMask {
2165 id: opacityEffect
2166 anchors.fill: decoratedWindow
2167 }
2168
2169 WindowControlsOverlay {
2170 id: touchControls
2171 anchors.fill: appDelegate
2172 target: appDelegate
2173 resizeArea: resizeArea
2174 enabled: false
2175 visible: enabled
2176 boundsItem: root.availableDesktopArea
2177
2178 onFakeMaximizeAnimationRequested: if (!appDelegate.maximized) fakeRectangle.maximize(amount, true)
2179 onFakeMaximizeLeftAnimationRequested: if (!appDelegate.maximizedLeft) fakeRectangle.maximizeLeft(amount, true)
2180 onFakeMaximizeRightAnimationRequested: if (!appDelegate.maximizedRight) fakeRectangle.maximizeRight(amount, true)
2181 onFakeMaximizeTopLeftAnimationRequested: if (!appDelegate.maximizedTopLeft) fakeRectangle.maximizeTopLeft(amount, true);
2182 onFakeMaximizeTopRightAnimationRequested: if (!appDelegate.maximizedTopRight) fakeRectangle.maximizeTopRight(amount, true);
2183 onFakeMaximizeBottomLeftAnimationRequested: if (!appDelegate.maximizedBottomLeft) fakeRectangle.maximizeBottomLeft(amount, true);
2184 onFakeMaximizeBottomRightAnimationRequested: if (!appDelegate.maximizedBottomRight) fakeRectangle.maximizeBottomRight(amount, true);
2185 onStopFakeAnimation: fakeRectangle.stop();
2186 onDragReleased: fakeRectangle.visible ? fakeRectangle.commit() : appDelegate.updateRestoredGeometry()
2187 }
2188
2189 WindowedFullscreenPolicy {
2190 id: windowedFullscreenPolicy
2191 }
2192 StagedFullscreenPolicy {
2193 id: stagedFullscreenPolicy
2194 active: root.mode == "staged" || root.mode == "stagedWithSideStage"
2195 surface: model.window.surface
2196 }
2197
2198 SpreadDelegateInputArea {
2199 id: dragArea
2200 objectName: "dragArea"
2201 anchors.fill: decoratedWindow
2202 enabled: false
2203 closeable: true
2204 stage: root
2205 dragDelegate: fakeDragItem
2206
2207 onClicked: {
2208 spreadItem.highlightedIndex = index;
2209 if (distance == 0) {
2210 priv.goneToSpread = false;
2211 }
2212 }
2213 onClose: {
2214 priv.closingIndex = index
2215 appDelegate.close();
2216 }
2217 }
2218
2219 WindowInfoItem {
2220 id: windowInfoItem
2221 objectName: "windowInfoItem"
2222 anchors { left: parent.left; top: decoratedWindow.bottom; topMargin: units.gu(1) }
2223 title: model.application.name
2224 iconSource: model.application.icon
2225 height: spreadItem.appInfoHeight
2226 opacity: 0
2227 z: 1
2228 visible: opacity > 0
2229 maxWidth: {
2230 var nextApp = appRepeater.itemAt(index + 1);
2231 if (nextApp) {
2232 return Math.max(iconHeight, nextApp.x - appDelegate.x - units.gu(1))
2233 }
2234 return appDelegate.width;
2235 }
2236
2237 onClicked: {
2238 spreadItem.highlightedIndex = index;
2239 priv.goneToSpread = false;
2240 }
2241 }
2242
2243 MouseArea {
2244 id: closeMouseArea
2245 objectName: "closeMouseArea"
2246 anchors { left: parent.left; top: parent.top; leftMargin: -height / 2; topMargin: -height / 2 + spreadMaths.closeIconOffset }
2247 readonly property var mousePos: hoverMouseArea.mapToItem(appDelegate, hoverMouseArea.mouseX, hoverMouseArea.mouseY)
2248 readonly property bool shown: dragArea.distance == 0
2249 && index == spreadItem.highlightedIndex
2250 && mousePos.y < (decoratedWindow.height / 3)
2251 && mousePos.y > -units.gu(4)
2252 && mousePos.x > -units.gu(4)
2253 && mousePos.x < (decoratedWindow.width * 2 / 3)
2254 opacity: shown ? 1 : 0
2255 visible: opacity > 0
2256 Behavior on opacity { LomiriNumberAnimation { duration: LomiriAnimation.SnapDuration } }
2257 height: units.gu(6)
2258 width: height
2259
2260 onClicked: {
2261 priv.closingIndex = index;
2262 appDelegate.close();
2263 }
2264 Image {
2265 id: closeImage
2266 source: "graphics/window-close.svg"
2267 anchors.fill: closeMouseArea
2268 anchors.margins: units.gu(2)
2269 sourceSize.width: width
2270 sourceSize.height: height
2271 }
2272 }
2273
2274 Item {
2275 // Group all child windows in this item so that we can fade them out together when going to the spread
2276 // (and fade them in back again when returning from it)
2277 readonly property bool stageOnProperState: root.state === "windowed"
2278 || root.state === "staged"
2279 || root.state === "stagedWithSideStage"
2280
2281 // TODO: Is it worth the extra cost of layering to avoid the opacity artifacts of intersecting children?
2282 // Btw, will involve more than uncommenting the line below as children won't necessarily fit this item's
2283 // geometry. This is just a reference.
2284 //layer.enabled: opacity !== 0.0 && opacity !== 1.0
2285
2286 opacity: stageOnProperState ? 1.0 : 0.0
2287 visible: opacity !== 0.0 // make it transparent to input as well
2288 Behavior on opacity { LomiriNumberAnimation {} }
2289
2290 Repeater {
2291 id: childWindowRepeater
2292 model: appDelegate.surface ? appDelegate.surface.childSurfaceList : null
2293
2294 delegate: ChildWindowTree {
2295 surface: model.surface
2296
2297 // Account for the displacement caused by window decoration in the top-level surface
2298 // Ie, the top-level surface is not positioned at (0,0) of this ChildWindow's parent (appDelegate)
2299 displacementX: appDelegate.clientAreaItem.x
2300 displacementY: appDelegate.clientAreaItem.y
2301
2302 boundsItem: root.availableDesktopArea
2303 decorationHeight: priv.windowDecorationHeight
2304
2305 z: childWindowRepeater.count - model.index
2306
2307 onFocusChanged: {
2308 if (focus) {
2309 // some child surface in this tree got focus.
2310 // Ensure we also have it at the top-level hierarchy
2311 appDelegate.claimFocus();
2312 }
2313 }
2314 }
2315 }
2316 }
2317 }
2318 }
2319 }
2320
2321 FakeMaximizeDelegate {
2322 id: fakeRectangle
2323 target: priv.focusedAppDelegate
2324 leftMargin: root.availableDesktopArea.x
2325 appContainerWidth: appContainer.width
2326 appContainerHeight: appContainer.height
2327 panelState: root.panelState
2328 }
2329
2330 WorkspaceSwitcher {
2331 id: workspaceSwitcher
2332 enabled: workspaceEnabled
2333 anchors.centerIn: parent
2334 height: units.gu(20)
2335 width: root.width - units.gu(8)
2336 background: root.background
2337 availableDesktopArea: root.availableDesktopArea
2338 onActiveChanged: {
2339 if (!active) {
2340 appContainer.focus = true;
2341 }
2342 }
2343 }
2344
2345 PropertyAnimation {
2346 id: shortRightEdgeSwipeAnimation
2347 property: "x"
2348 to: 0
2349 duration: priv.animationDuration
2350 }
2351
2352 SwipeArea {
2353 id: rightEdgeDragArea
2354 objectName: "rightEdgeDragArea"
2355 direction: Direction.Leftwards
2356 anchors { top: parent.top; right: parent.right; bottom: parent.bottom }
2357 width: root.dragAreaWidth
2358 enabled: root.spreadEnabled
2359
2360 property var gesturePoints: []
2361 property bool cancelled: false
2362
2363 property real progress: -touchPosition.x / root.width
2364 onProgressChanged: {
2365 if (dragging) {
2366 draggedProgress = progress;
2367 }
2368 }
2369
2370 property real draggedProgress: 0
2371
2372 onTouchPositionChanged: {
2373 gesturePoints.push(touchPosition.x);
2374 if (gesturePoints.length > 10) {
2375 gesturePoints.splice(0, gesturePoints.length - 10)
2376 }
2377 }
2378
2379 onDraggingChanged: {
2380 if (dragging) {
2381 // A potential edge-drag gesture has started. Start recording it
2382 gesturePoints = [];
2383 cancelled = false;
2384 draggedProgress = 0;
2385 } else {
2386 // Ok. The user released. Did he drag far enough to go to full spread?
2387 if (gesturePoints[gesturePoints.length - 1] < -spreadItem.rightEdgeBreakPoint * spreadItem.width ) {
2388
2389 // He dragged far enough, but if the last movement was a flick to the right again, he wants to cancel the spread again.
2390 var oneWayFlickToRight = true;
2391 var smallestX = gesturePoints[0]-1;
2392 for (var i = 0; i < gesturePoints.length; i++) {
2393 if (gesturePoints[i] <= smallestX) {
2394 oneWayFlickToRight = false;
2395 break;
2396 }
2397 smallestX = gesturePoints[i];
2398 }
2399
2400 if (!oneWayFlickToRight) {
2401 // Ok, the user made it, let's go to spread!
2402 priv.goneToSpread = true;
2403 } else {
2404 cancelled = true;
2405 }
2406 } else {
2407 // Ok, the user didn't drag far enough to cross the breakPoint
2408 // Find out if it was a one-way movement to the left, in which case we just switch directly to next app.
2409 var oneWayFlick = true;
2410 var smallestX = rightEdgeDragArea.width;
2411 for (var i = 0; i < gesturePoints.length; i++) {
2412 if (gesturePoints[i] >= smallestX) {
2413 oneWayFlick = false;
2414 break;
2415 }
2416 smallestX = gesturePoints[i];
2417 }
2418
2419 if (appRepeater.count > 1 &&
2420 (oneWayFlick && rightEdgeDragArea.distance > units.gu(2) || rightEdgeDragArea.distance > spreadItem.rightEdgeBreakPoint * spreadItem.width)) {
2421 var nextStage = appRepeater.itemAt(priv.nextInStack).stage
2422 for (var i = 0; i < appRepeater.count; i++) {
2423 if (i != priv.nextInStack && appRepeater.itemAt(i).stage == nextStage) {
2424 appRepeater.itemAt(i).playHidingAnimation()
2425 break;
2426 }
2427 }
2428 appRepeater.itemAt(priv.nextInStack).playFocusAnimation()
2429 if (appRepeater.itemAt(priv.nextInStack).stage == ApplicationInfoInterface.SideStage && !sideStage.shown) {
2430 sideStage.show();
2431 }
2432
2433 } else {
2434 cancelled = true;
2435 }
2436
2437 gesturePoints = [];
2438 }
2439 }
2440 }
2441
2442 GestureAreaSizeHint {
2443 anchors.fill: parent
2444 }
2445 }
2446
2447 TabletSideStageTouchGesture {
2448 id: triGestureArea
2449 objectName: "triGestureArea"
2450 anchors.fill: parent
2451 enabled: false
2452 property Item appDelegate
2453
2454 dragComponent: dragComponent
2455 dragComponentProperties: { "appDelegate": appDelegate }
2456
2457 onPressed: {
2458 function matchDelegate(obj) { return String(obj.objectName).indexOf("appDelegate") >= 0; }
2459
2460 var delegateAtCenter = Functions.itemAt(appContainer, x, y, matchDelegate);
2461 if (!delegateAtCenter) return;
2462
2463 appDelegate = delegateAtCenter;
2464 }
2465
2466 onClicked: {
2467 priv.toggleSideStage()
2468 }
2469
2470 onDragStarted: {
2471 // If we're dragging to the sidestage.
2472 if (!sideStage.shown) {
2473 sideStage.show();
2474 }
2475 }
2476
2477 onDropped: {
2478 // Hide side stage if the app drag was cancelled
2479 if (!priv.sideStageDelegate) {
2480 sideStage.hide();
2481 }
2482 }
2483
2484 Component {
2485 id: dragComponent
2486 SurfaceContainer {
2487 property Item appDelegate
2488
2489 surface: appDelegate ? appDelegate.surface : null
2490
2491 consumesInput: false
2492 interactive: false
2493 focus: false
2494 requestedWidth: appDelegate ? appDelegate.requestedWidth : 0
2495 requestedHeight: appDelegate ? appDelegate.requestedHeight : 0
2496
2497 width: units.gu(40)
2498 height: units.gu(40)
2499
2500 Drag.hotSpot.x: width/2
2501 Drag.hotSpot.y: height/2
2502 // only accept opposite stage.
2503 Drag.keys: {
2504 if (!surface) return "Disabled";
2505
2506 if (appDelegate.stage === ApplicationInfo.MainStage) {
2507 if (appDelegate.application.supportedOrientations
2508 & (Qt.PortraitOrientation|Qt.InvertedPortraitOrientation)) {
2509 return "MainStage";
2510 }
2511 return "Disabled";
2512 }
2513 return "SideStage";
2514 }
2515 }
2516 }
2517 }
2518}